' ***************************************************************************************
'  µðºñ º¯Á¶µ¥ÀÌÅÍ º¹±¸ ½ºÅ©¸³Æ® 
'  ¹ö Á¯    : v1.0                                                                   
' ***************************************************************************************
Option Explicit
'On Error Resume Next

' »èÁ¦ÇÒ ÀÚ¹Ù½ºÅ©¸³Æ® ±¸¹®
' ´ÙÁßÀÔ·ÂÀÌ °¡´ÉÇϸç, ´ÙÁßÀԷ½à | ·Î ÀÔ·ÂÇϽñ⠹ٶø´Ï´Ù.
Const strReplace = "<script src=http://ojkqn.cn></script>|<script src=http://wefd4.cn>|" 
Const strDBServerIP = "127.0.0.1"    ' Á¢¼ÓÇÒ µ¥ÀÌÅͺ£À̽º ¼­¹ö IP
Const strSQLuser = "sa"                ' Á¢¼ÓÇÒ µ¥ÀÌÅͺ£À̽º ¾ÆÀ̵ð
Const strSQLpass = "1230"              ' Á¢¼ÓÇÒ µ¥ÀÌÅͺ£À̽º Æнº¿öµå
Const strSQLBD = "pubs"                 ' Á¢¼ÓÇÒ µ¥ÀÌÅͺ£À̽º À̸§

Dim CRLF, TAB :TAB  = CHR( 9 ):CRLF = CHR( 13 ) & CHR( 10 )
Dim AdCn,connectionstring,SQL,DBdata,arrDBData, arrDBData2

Dim SQL_Tables, SQL_Tables_Exists_Javascript, ColumnsArrDBdata, ColumnsTotal, TableArrDBdata, TableTotal, SQL_tmp
Dim i, j, db_table, db_column, db_xtype, db_type, db_owner, db_len
Dim TablecolumnCheck, SQL_Tables_Replace_Javascript
Dim KeyName, Key_code, Key_entry, arr_Replacetxt, Replacetxt

arr_Replacetxt = split(strReplace,"|")

SQL_Tables = "select o.name, c.name, c.xtype, type = (select t.name from systypes t where t.name <> 'sysname' and t.xtype=c.xtype ) , owner = user_name(uid) " & _
            " ,Len = (select  case when t.name in (N'nchar', N'nvarchar') then c.length/2 else c.length end from systypes t where t.name <> 'sysname' and t.xtype=c.xtype ) " & _
            " from dbo.syscolumns c " & _
            " Left Join (select name,id,uid from dbo.sysobjects where xtype='U' " & _
            " and (case when (OBJECTPROPERTY(id, N'IsMSShipped')=1) then 1 else OBJECTPROPERTY(id, N'IsSystemTable') end)=0 ) o " & _
            " on c.id=o.id where o.name is not null and c.xtype in (35, 99, 167, 175, 231, 239) " & _
            " order by o.name, c.name "

' 35  -- text
' 99  -- ntext
' 167 -- varchar
' 175 -- char
' 231 -- nvarchar
' 239 -- nchar

connectionstring = "Provider=SQLOLEDB.1;Data Source= "&strDBServerIP&";Initial Catalog="&strSQLBD&";user id = '"&strSQLuser&"';password='"&strSQLpass&"' "


SQL = SQL_Tables
Set AdCn = CreateObject("ADODB.Connection")
AdCn.open = connectionstring
set DBdata = AdCn.Execute(SQL)
IF Not DBdata.Eof then
  ColumnsArrDBdata = DBdata.GetRows()
  ColumnsTotal = UBound(ColumnsArrDBdata, 2)+1
else
  ColumnsTotal = 0
end if
DBdata.Close
Set DBdata = Nothing

wscript.echo "Ä÷³°¹¼ö : "&ColumnsTotal
If ColumnsTotal>0 then
	For i=1 to ColumnsTotal
      db_table = ColumnsArrDBdata(0,i-1)
      db_column = ColumnsArrDBdata(1,i-1)
      db_xtype = ColumnsArrDBdata(2,i-1)
      db_type = ColumnsArrDBdata(3,i-1)
      db_owner = ColumnsArrDBdata(4,i-1)
      db_len = ColumnsArrDBdata(5,i-1)
      
      SQL = "select count(*) From ["&db_owner&"].["&db_table&"] where CHARINDEX('<script',["&db_column&"]) > 0 "

      set DBdata = AdCn.Execute(SQL)
      IF Not DBdata.Eof then
        	arrDBData = DBdata.GetRows()
        	TablecolumnCheck = arrDBData(0,0)
      else
      	  TablecolumnCheck = 0
      end if
      DBdata.Close
      Set DBdata = Nothing
      
      if TablecolumnCheck > 0 then
        If db_xtype <> 35 and db_xtype <> 99 then
          For each Replacetxt in arr_Replacetxt
            wscript.echo "["&db_owner&"].["&db_table&"] ¿¡¼­ "&db_column&" Ä÷³¿¡ ´ëÇÑ "&Replacetxt&" »èÁ¦Áß..."
            SQL = "Update ["&db_owner&"].["&db_table&"] Set "&db_column&" = replace("&db_column&",'"&Replacetxt&"','')"
            AdCn.Execute(SQL)
          Next
        Else
          SQL = "select name from syscolumns  where id in (select id from sysobjects where name = '"&db_table&"') "
          SQL = SQL&"and colid in (select sik.colid from sysindexkeys sik join sysobjects so on sik.id = so.id where sik.indid = 1 and so.name = '"&db_table&"')"
          set DBdata = AdCn.Execute(SQL)
          IF Not DBdata.Eof then
            arrDBData2 = DBdata.GetRows()
            KeyName = arrDBData2(0,0)
          else
        	  KeyName = ""
          end if
          DBdata.Close
          Set DBdata = Nothing

          If Len(KeyName) > 0 then
            SQL = "select "&KeyName&","&db_column&" From ["&db_owner&"].["&db_table&"] "
            set DBdata = AdCn.Execute(SQL)
            IF Not DBdata.Eof then
              TableArrDBdata = DBdata.GetRows()
              TableTotal = UBound(TableArrDBdata, 2)+1
            else
        	    TableTotal = 0
            end if
            DBdata.Close
            Set DBdata = Nothing

            If TableTotal > 0 then
              for j=1 to TableTotal
                Key_code = TableArrDBdata(0,j-1)
                Key_entry = TableArrDBdata(1,j-1)
                If Len(Key_entry) > 0 then
                  Key_entry = Replace(Key_entry,"'","''")
                  For each Replacetxt in arr_Replacetxt
                    Key_entry = Replace(Key_entry,Replacetxt,"")
                  Next
                  wscript.echo "["&db_owner&"].["&db_table&"] ¿¡¼­ "&db_column&" Ä÷³¿¡ ´ëÇÑ "&KeyName&"ÀÇ "&Key_code&"°ª »èÁ¦Áß..."
                  SQL = "update ["&db_owner&"].["&db_table&"] Set "&db_column&" = '"&Key_entry&"' where "&KeyName&"="&Key_code
                  AdCn.Execute(SQL)
                End if
              Next
            End if
          End if
        End if
        
      End if
	next
Else
  wscript.echo "Ä÷³ÀÌ ¾ø½À´Ï´Ù."
end if
      
AdCn.Close
set AdCn=Nothing